안녕하세요

어찌어찌 하다가 완성은 했는데 문자열이 깨져서 나와서요

Sub test()

    Dim FilePath As String

    Dim LineFromFile As String

    Dim LineItems() As String

    Dim row_number As Integer

    'FilePath = Application.DefaultFilePath & "\authors.csv"

    FilePath = "C:\jhj\ze.csv"

    Open FilePath For Input As #1

    row_number = 0

    Do Until EOF(1)

        Line Input #1, LineFromFile

        LineItems = Split(LineFromFile, ",")

        ActiveCell.Offset(row_number, 0).Value = LineItems(0)

        ActiveCell.Offset(row_number, 1).Value = LineItems(1)

        ActiveCell.Offset(row_number, 2).Value = LineItems(2)

        row_number = row_number + 1

    Loop

    Close #1

End Sub

혹시 위 에서 문자열 한글 문자열을 utf8 euc-kr 등을 바꾸려면 어떻게 해야 하는지 문의 드립니다.

UTF-8로 읽고 쓰기

http://blog.naver.com/atmyhome/90154596931

[이하 위 링크에서 퍼온 코드 ]

Function TextStrimRead(strPathName As String) As String
Dim objStream As Object
    Set objStream = CreateObject("ADODB.Stream")
    objStream.Open
    objStream.Type = 2 'adTypeText
    objStream.Charset = "UTF-8"
    objStream.LoadFromFile strPathName
    TextStrimRead = objStream.ReadText
    Set objStream = Nothing
End Function

   
Sub TextStrimWrite(strPathName As String, strString As String)
Dim objStream As Object
    Set objStream = CreateObject("ADODB.Stream")
    objStream.Open
    objStream.Type = 2 'adTypeText
    objStream.Charset = "UTF-8"
    objStream.WriteText strString
    objStream.SaveToFile strPathName, 2 'adSaveCreateOverWrite
    Set objStream = Nothing
er:
End Sub

Sub test()
    '경로는 자신의 경로로 수정하세요.

    'UTF-8형식의 Sample1.txt 파일이 있어야 실행됩니다.
    '텍스트 파일을 읽어오는 예시
    Debug.Print TextStrimRead("C:\Documents and Settings\cjj_biz\바탕 화면\Sample1.txt")
    '
    '텍스트 파일에 쓰는 예시
    TextStrimWrite "C:\Documents and Settings\cjj_biz\바탕 화면\Sample1.txt", "연습입니다."
End Sub